Section - Include lines

Include Status Line Removal by Emily Short.

Section - Your gamebook pages

[PUT ALL OF YOUR GAMEBOOK PAGES IN HERE]







Table of Help
Narrative
"[bold type]Welcome to the help page.[roman type][paragraph break]You're playing a digital gamebook, which works just like a Choose Your Own Adventure.[paragraph break]As you play the gamebook, you will be presented with sections of a story, broken into 'pages'. At the end of each page, you'll be given some options on which way you'd like the story to continue, and asked to make a choice. You'll know when that happens because you will see the phrase 'YOUR CHOICE...'[paragraph break]To make a choice, simply type in the word or words that correspond to the choice you want to make.[paragraph break]For example, you might be given a choice between attacking a giant python or running away from it. In the story, the choice might be presented to you like this: 'To attack the python, type 'ATTACK PYTHON'. Or to run away, type 'FLEE''.[paragraph break]If you wanted to attack the python, you would simply type the words 'ATTACK PYTHON' (without the apostrophes), ensuring you typed the space inbetween. You needn't worry about typing any of the words in capitals as the gamebook will recognise both upper and lower case letters.[paragraph break]In addition to the choices on each page, there are some special commands you can enter at any time.[paragraph break]"
"[bold type]The special commands are:[roman type][paragraph break]'HELP' -- this command will bring up the help page.[paragraph break]'COMMANDS' -- this command will show the list of special commands available to you.[paragraph break]'STORY' -- this command will reprint the current page, including the story and the choices available to you.[paragraph break]'CHOICES' -- this command will reprint the choices available to you for the current page.[paragraph break]'BACK' -- this command will let you go back one page in the story. You can't use this command twice in a row.[paragraph break]'RESTART' -- this command will allow you to restart the gamebook from the beginning.[paragraph break]'SAVE' -- this command will let you save your place in the gamebook, kind of like a bookmark.[paragraph break]'RESTORE' -- this command will let you load a saved game. Think of it like returning to a page you've bookmarked.[paragraph break]'QUIT' -- this command will let you end the gamebook story, without saving your place.[paragraph break]You will now be returned to your place in the gamebook. If you need to refresh your memory on where the story is up to, type 'STORY' to reprint the current page.[paragraph break]"

[PUT ALL OF YOUR GAMEBOOK PAGES IN THE SPACE ABOVE HERE]

Section - Mechanics

Chapter - Setting up the gamebook

CurrentPage is a table name that varies. CurrentPage is Table of First Page.
OldPage is a table name that varies. OldPage is Table of First Page.

Rule for printing the banner text: do nothing.
Rule for printing the name of a room: do nothing.

Gamebook is a room.
Rule for printing the locale description of the Gamebook:
	repeat through CurrentPage:
		say "[narrative entry]";
	say "[paragraph break]".

When play begins:
	now the command prompt is "YOUR CHOICE... ".

Chapter - Reading the player's command

After reading a command:
	if the player's command is a topic listed in CurrentPage:
		now OldPage is CurrentPage;
		now CurrentPage is link entry;
		say "[paragraph break]";
		Repeat through CurrentPage:
			say "[narrative entry]";
		say "[paragraph break]";
		reject the player's command;
	otherwise if the player's command matches "help":
		say "[paragraph break]";
		repeat through Table of Help:
			say "[narrative entry]";
		say "[paragraph break]";
		reject the player's command;
	otherwise if the player's command matches "commands":
		say "[paragraph break]";
		repeat with N running from 2 to the number of rows in the Table of Help:
			choose row N in Table of Help;
			say "[narrative entry]";
		say "[paragraph break]";
		reject the player's command;
	otherwise if the player's command matches "story":
		say "[paragraph break]";
		repeat through CurrentPage:
			say "[narrative entry]";
		say "[paragraph break]";
		reject the player's command;
	otherwise if the player's command matches "choices":
		say "[paragraph break]";
		repeat with N running from 2 to the number of rows in the CurrentPage:
			choose row N in CurrentPage;
			say "[narrative entry]";
		say "[paragraph break]";
		reject the player's command;
	otherwise if the player's command matches "back":
		if CurrentPage is OldPage:
			say "[paragraph break]";
			say "You can't go back a page from here.";
			reject the player's command;
		otherwise:
			now CurrentPage is OldPage;
			say "[paragraph break]";
			repeat through CurrentPage:
				say "[narrative entry]";
			say "[paragraph break]";
			reject the player's command;
	otherwise if the player's command does not match "save/restore/quit/restart":
		say "[paragraph break]Your choice wasn't understood. If you need help to play this gamebook, type 'HELP'.[paragraph break]";
		reject the player's command.